Vrftjkry

UPDATED-STATEMENT: 20181118@205016@SUN A suggestion was made to manually focus the Virtual Desktop of my choice, but this eliminates me from doing other tasks on another Virtual Desktop. Still waiting for a valid take-care-ofitself solution.

UPDATED-STATEMENT: 20181118@210851@SUN There is no way autohotkey can work with moving apps to a specific Virtual Desktop on it's own without dll-calls (*see below*). In other words, the use of dll-files is required for the time being that is Windows language and not as convenient as an ahk-statement. Who knows, maybe ahk can implement this function someday to keep it lightweight and add it to their statement-library.

SPECIFICATION:

win10_1803_17134.407

autohotkeyahk_1.1.30.00_20180822

Speed is everything if it does affect you sitting on your chair in front of a computer screen.

WHY I USE AHK

Using Autohotkey in Windows 10 to open up frequently used apps which will not duplicate opening up a program if it has already launched (IfWinNotExist). Then, move them to where I prefer each app to be (WinMove). I have set a timer (Sleep) because some apps open up slower than others (I would be interested to know if there is a better way to do this). I like ahk for how lightweight it is, but there's Windows 10 related functions that aren't documented from them like Virtual Desktop involvement.

PROBLEM

Problem is that there isn't a way to use WinMove for specifying a Virtual Desktop for win10 to launch an application in. So I struggle running my frequentlyusedapps-script and going into another Virtual Desktop to open up other apps simultaneously. This is because what ever Virtual Desktop i'm focusing on is what my frequentlyusedapps-script will move the window to.

QUESTION

How to have autohotkey move an application to a Virtual Desktop of my choice? I don't think it's possible with ahk-WinMove If the virtualdesktop-number isn't created then the script will obviously fail to move the app, but this isn't my focus just yet. I could otherwise create the appropriate number of Virtual Desktops prior to launching my frequentlyusedapps-script. What I mean by having a way for ahk to achieve this is to be pure ahk code and not fork/branch that will probably be not updated for the unfortunate reasons. If it does have to come from a branched project then let's discuss what ahk elements they're using to involve Virtual Desktop to move windows to a specific one.

!^+o::

  IfWinNotExist, ahk_exe program1.exe

    Run "C:Dirprogram1.exe"

    WinWait, ahk_exe program1.exe

    WinMove, ahk_exe program1.exe,, 953, 61, 967, 1019

    TrayTip, openfrequentlyusedapps, ok, 1,

  IfWinNotExist, ahk_exe program2.exe

    Run "C:Dirprogram2.exe"

    WinWait, ahk_exe program2.exe

    WinMove, ahk_exe program2.exe,, -7, 61, 813, 516

    TrayTip, openfrequentlyusedapps, ok, 1,

SOLUTION

• As per @miroxlav, "there is no way Autohotkey can do this with their current statements." Although not impossible, but requires more effort as it's now Windows language is using ahk w/ dll-calls.
  
  
  
  
  • It would help a lot of someone is able to show how this even works
  
  
  
  

• What is Virtual Desktop?


• What is autohotkey?


• What hotkeys can I use with ahk?


• What is ahk-WinExist or IfWinNotExist?


• What is ahk-Sleep?


• What is ahk-WinMove?


• Why use ahk-Sleep over ahk-WinWait to not do a single action until an app has been opened and ready to move via WinMove?
  
  
  
  
  • Good question as I wasn't aware, but i'm using WinWait now and it's so much more efficient
  
  
  
  

Go with keyboard shortcuts.

Inside the script, when you sequentially start your apps, in the middle of your sequence simply switch to the next desktop by sending Ctrl+Win+→:

;here you run and position your windows

Run app1

Move app1  'etc.

WinWait app1window   'wait until app window is open



;switch to next desktop*  (see note below the code)

Send ^#{Right}



;opening apps on next desktop

Run app2

Move app2  'etc.

*) If you do not have that "next desktop" prepared at the time, send Ctrl+Alt+D instead to create and open it.

For more, see section Virtual desktops keyboard shortcuts in the official list of Windows keyboard shortcuts.

Update:

Functionality regarding other desktops as you request it is currently not present directly in AHK statements. You may be able to achieve it by using DLL calls from within the AHK.

Try this

#NoEnv

#SingleInstance Force

SetBatchLines -1

SetWorkingDir %A_ScriptDir%



main(), return



; Ctrl + number from 1 to 9

switch_to_desktop:

    switchToDesktop(StrReplace(A_ThisHotkey, "^", , , 1) - 1)

    Focus()

return



; Ctrl + Win + number from 1 to 9

move_A_to_desktop:

    WinGet, active_id, ID, A

    If !IsWindowOnCurrentVirtualDesktop(active_id)

        return

    IniRead, active_desktop, active_desktop.ini, active_desktop, desktop    

    WinHide ahk_id %active_id%

    switchToDesktop(StrReplace(A_ThisHotkey, "^#", , , 1) - 1)

    WinShow ahk_id %active_id%

    switchToDesktop(active_desktop - 1) 

return



; Ctrl + Shift + number from 1 to 9

move_A_and_switch_to_desktop:

    WinGet, active_id, ID, A

    If !IsWindowOnCurrentVirtualDesktop(active_id)

        return

    WinHide ahk_id %active_id%

    switchToDesktop(StrReplace(A_ThisHotkey, "^+", , , 1) - 1)

    WinShow ahk_id %active_id%

    WinActivate, ahk_id %active_id%

    Focus()

return



; https://autohotkey.com/boards/viewtopic.php?f=6&t=14881&hilit=Virtual+Desktop

switchToDesktop(idx) {

    global ppDesktopManager, IID_IVirtualDesktop

    DllCall(vtable(ppDesktopManager, 7), "Ptr", ppDesktopManager, "Ptr*", pDesktops)

    if (pDesktops) {

        DllCall(vtable(pDesktops, 4), "Ptr", pDesktops, "UInt", idx, "Ptr", &IID_IVirtualDesktop, "Ptr*", VirtualDesktop)

        if (VirtualDesktop) {

            DllCall(vtable(ppDesktopManager, 9), "Ptr", ppDesktopManager, "Ptr", VirtualDesktop)

            ObjRelease(VirtualDesktop) ; I assume these should be freed

        }

        ObjRelease(pDesktops)

    }

    If (idx = "")

        Index := 1

    else

        Index := idx +1     

    IniWrite, %Index%, active_desktop.ini, active_desktop, desktop

    CoordMode, ToolTip, Screen

    ToolTip, Desktop %Index%, (A_ScreenWidth -20), 0

}



main() {

    OnExit, cleanup

    OnMessage(DllCall("RegisterWindowMessage", Str, "TaskbarCreated"), "WM_TASKBARCREATED")

    static ImmersiveShell := ComObjCreate("{C2F03A33-21F5-47FA-B4BB-156362A2F239}", "{00000000-0000-0000-C000-000000000046}")

    global IID_IVirtualDesktop, ppDesktopManager



    try ppDesktopManager := ComObjQuery(ImmersiveShell, "{C5E0CDCA-7B6E-41B2-9FC4-D93975CC467B}", "{f31574d6-b682-4cdc-bd56-1827860abec6}")

    if (!ppDesktopManager)

        ppDesktopManager := ComObjQuery(ImmersiveShell, "{C5E0CDCA-7B6E-41B2-9FC4-D93975CC467B}", "{AF8DA486-95BB-4460-B3B7-6E7A6B2962B5}")

    GUID(IID_IVirtualDesktop, "{FF72FFDD-BE7E-43FC-9C03-AD81681E88E4}")

    ObjRelease(ImmersiveShell)  



    Loop 9

    {

        Hotkey, ^%A_Index%, switch_to_desktop

        Hotkey, ^#%A_Index%, move_A_to_desktop

        Hotkey, ^+%A_Index%, move_A_and_switch_to_desktop       

    }

    return



cleanup:

    if (ppDesktopManager)

        ObjRelease(ppDesktopManager)

    ExitApp

}



WM_TASKBARCREATED() {

    Reload

}



vtable(ptr, n) {

    ; NumGet(ptr+0) returns the address of the object's virtual function

    ; table (vtable for short). The remainder of the expression retrieves

    ; the address of the nth function's address from the vtable.

    return NumGet(NumGet(ptr+0), n*A_PtrSize)

}



GUID(ByRef GUID, sGUID) { ; Converts a string to a binary GUID

    VarSetCapacity(GUID, 16, 0)

    DllCall("ole32CLSIDFromString", "Str", sGUID, "Ptr", &GUID)

}



Focus() { ; Give focus to the foremost window on the desktop.

    WinGet, id, list

    Loop, %id%

    {

        this_ID := id%A_Index%

        If IsWindowOnCurrentVirtualDesktop(this_ID)

        {

            WinActivate, ahk_id %this_ID%

                break

        }

    }

}



; https://autohotkey.com/boards/viewtopic.php?p=64295#p64295

; Indicates whether the provided window is on the currently active virtual desktop.

IsWindowOnCurrentVirtualDesktop(hWnd) {

    onCurrentDesktop := ""

    CLSID := "{aa509086-5ca9-4c25-8f95-589d3c07b48a}" 

    IID := "{a5cd92ff-29be-454c-8d04-d82879fb3f1b}"

    IVirtualDesktopManager := ComObjCreate(CLSID, IID)  

    Error := DllCall(NumGet(NumGet(IVirtualDesktopManager+0), 3*A_PtrSize), "Ptr", IVirtualDesktopManager, "Ptr", hWnd, "IntP", onCurrentDesktop)

    ObjRelease(IVirtualDesktopManager)  

    if !(Error=0)

        return false, ErrorLevel := true

    return onCurrentDesktop, ErrorLevel := false

}